home *** CD-ROM | disk | FTP | other *** search
/ Games of Daze / Infomagic - Games of Daze (Summer 1995) (Disc 1 of 2).iso / x2ftp / msdos / docs / winer / wordwrap.bas < prev   
Encoding:
BASIC Source File  |  1992-05-13  |  1.0 KB  |  32 lines
  1. '*********** WORDWRAP.BAS - shows how to wrap words within a text window
  2.  
  3. 'Copyright (c) 1992 Ethan Winer
  4.  
  5. DEFINT A-Z
  6. DECLARE SUB WordWrap (X$, Wide, LeftMargin)
  7.  
  8. SUB WordWrap (X$, Wide, LeftMargin) STATIC
  9.  
  10.     Length = LEN(X$)            'remember the length
  11.     Pointer = 1                 'start at the beginning of the string
  12.     IF LeftMargin = 0 THEN LeftMargin = 1       'trap an illegal margin
  13.  
  14.     'Scan a block of Wide characters backwards, looking for a blank.
  15.     'Stop at the first blank or if we reach the beginning of the string.
  16.     DO
  17.        FOR X = Pointer + Wide TO Pointer STEP -1
  18.            IF MID$(X$, X, 1) = " " OR X = Length + 1 THEN
  19.               LOCATE , LeftMargin
  20.               PRINT MID$(X$, Pointer, X - Pointer);
  21.               Pointer = X + 1
  22.               WHILE MID$(X$, Pointer, 1) = " "
  23.                  Pointer = Pointer + 1
  24.               WEND
  25.               IF POS(0) > 1 THEN PRINT
  26.               EXIT FOR
  27.            END IF
  28.        NEXT
  29.     LOOP WHILE Pointer < Length
  30.  
  31. END SUB
  32.